set more off


/* Table 2 -- LLSV 1998 */

local i 1
foreach indepvar of varlist nant_dir adri97d_prevote_proxvote DLLSf_ADRI {
reg c3pri `indepvar' cred_in  leg_resv c1sh_1vo mand_div account frsp_mom scan_mom ger_mom rule_law x_gini1994 lgdp_pc loggnp94, robust
estimates store table2_`i++'
reg concentr `indepvar' cr1994  leg_resv c1sh_1vo mand_div account frsp_mom scan_mom ger_mom rule_law x_gini1994 lgdp_pc loggnp94 , robust
estimates store table2_`i++'
}
esttab table2_* using table2, replace rtf label title(Regression specification of LLSV (1998)) nomtitles nodepvars order(nant_dir adri97d_prevote_proxvote DLLSf_ADRI cred_ind cr1994) r2 se star(* 0.10 ** 0.05 *** 0.01) b(%4.3f) addnotes(`" "' `" "' `" "')
estimates drop _all




/* TABLE 4 -- LLSV 1997 */

local i 1
foreach depvar of varlist excapgnp listpc94llsv ipo_pop {
reg `depvar' nant_dir gdp_grow loggnp94  rule_law if mi(adri97d_prevote_proxvote)==0
estimates store table4_`i++'
reg `depvar' nant_dir gdp_grow loggnp94  rule_law frsp_mom ger_mom scan_mom if mi(adri97d_prevote_proxvote)==0
estimates store table4_`i++'
}
esttab table4_* using table4, replace rtf title(Regression specifications of LLSV (1997)) keep(nant_dir) noobs se star(* 0.10 ** 0.05 *** 0.01) nonotes b(%3.2f)
estimates drop _all

local i 1
foreach depvar of varlist excapgnp listpc94llsv ipo_pop {
reg `depvar' adri97d_prevote_proxvote gdp_grow loggnp94  rule_law if mi(adri97d_prevote_proxvote)==0
estimates store table4_`i++'
reg `depvar' adri97d_prevote_proxvote gdp_grow loggnp94  rule_law frsp_mom ger_mom scan_mom if mi(adri97d_prevote_proxvote)==0
estimates store table4_`i++'
}
esttab table4_* using table4, append rtf keep(adri97d_prevote_proxvote) nomtitles nodepvars nonumbers noobs se star(* 0.10 ** 0.05 *** 0.01) b(%3.2f) nonotes
estimates drop _all


local i 1
foreach depvar of varlist excapgnp listpc94llsv ipo_pop {
reg `depvar' DLLSf_ADRI gdp_grow loggnp94  rule_law if mi(adri97d_prevote_proxvote)==0
estimates store table4_`i++'
reg `depvar' DLLSf_ADRI gdp_grow loggnp94  rule_law frsp_mom ger_mom scan_mom if mi(adri97d_prevote_proxvote)==0
estimates store table4_`i++'
}
esttab table4_* using table4, append rtf keep(DLLSf_ADRI) nomtitles nolines nodepvars nonumbers se star(* 0.10 ** 0.05 *** 0.01)  b(%3.2f) addnotes("All regressions control for GDP growth (average 1970-1993), log(GNP 1994), and rule of law." "The models underlying columns 2, 4, and 6 contain legal origin dummies." `" "' `" "')
estimates drop _all


/* Table 5 -- Johnson et al. 2000 */

reg purchase nant_dir eastasia reserve
estimates store tab51
reg purchase augmented_recoded_adri eastasia reserve
estimates store tab52
reg purchase DLLSf_ADRI eastasia reserve
estimates store tab53

esttab tab5* using table5, replace rtf title(Table 5 -- Regression specification of Johnson et al. (2000)) depvars order(nant_dir augmented_recoded_adri DLLSf_ADRI) r2 se star(* 0.10 ** 0.05 *** 0.01) b(%4.3f) obslast
estimates drop _all


/* Table 6 -- Wurgler 2000 */
local j 0
foreach rights of varlist w_llsv_rights w_oldnew_rights w_revised_rights_final {
reg w_eta `rights' if mi(w_oldnew_rights)==0, robust
estimates store table6_`j++'
reg w_eta w_synch w_soe w_fd w_gdp `rights' if mi(w_oldnew_rights)==0, robust
estimates store table6_`j++'
}

foreach rights of varlist w_llsv_rights w_oldnew_rights w_revised_rights_final {
reg w_diffeta w_fd `rights' if mi(w_oldnew_rights)==0, robust
estimates store table6_`j++'
reg w_diffeta w_synch w_soe w_fd w_gdp `rights' if mi(w_oldnew_rights)==0, robust
estimates store table6_`j++'
}

esttab table6_* using table6, replace rtf title(Table 6 -- Regression specifications of Wurgler (2000)) order(w_llsv_rights w_oldnew_rights w_revised_rights_final) depvars r2 se obslast star(* 0.10 ** 0.05 *** 0.01) b(%4.3f)
estimates drop _all


/* the end */